Cet article est la suite du billet Comment écrire une formule dans une plage de cellules en VBA ?

Nous allons apprendre comment écrire des formules plus complexes.
Pour tous les plages de données évoquées plus bas la cellule de départ est la cellule A1 et la première ligne contient les étiquettes de colonnes.

Comment écrire une formule plus complexe dans une cellule ?

Prenons la formule NB.SI dont la syntaxe est NB.SI(Plage;Critère) et qui a pour but de compter le nombre de cellules répondant au critère.
Pour illustrer notre exemple, imaginons une plage de données A1:F31 dont les cellules de la colonne F contiennent le nom d’une ville.
Le but sera donc de compter le nombre de fois que le critère (ici Marseille) se retrouve dans la plage F2:F31
la formule sera donc

=NB.SI($F$2:$F$31;"Marseille")

Soit en VBA

=COUNTIF($F$2:$F$31,"Marseille")

après avoir utilisé l’astuce présentée dans le premier article et que nous rappelons ci-dessous.

Formule plus complexeComment traiter les constantes alphanumériques dans une formule ?

Si nous plaçons telle quelle cette chaîne de caractères comme constante ou comme variable suivant l’exemple ci-dessous, nous aurons immanquablement un message « Erreur de compilation, fin d’instruction

Const myFormula As String = "=COUNTIF($F$2:$F$31,"Marseille")"

Pour pallier ce problème, nous devons doubler les guillemets soit

Const myFormula As String = "=COUNTIF($F$2:$F$31,""Marseille"")"

Ce qui évidemment n’est pas simple à relire surtout si nous avons beaucoup de constante alphanumérique dans une formule comme cet exemple ci-dessous avec la formule SOMMEPROD dont la valeur renvoyée équivaut à un NB.SI avec deux critères (Les personnes travaillant à Marseille au service Achat).

Const myFormula As String = "=SUMPRODUCT( ($D$2:$D$31=""Achat"") * ($F$2:$F$31=""Marseille"") )"

Comme on peut le constater, l’encodage de la formule devient très rapidement rébarbatif.

Utiliser des balises

Pour éviter de s’encombrer d’une multitude de guillemets difficile à gérer, nous allons utiliser une balise que nous remplacerons par la valeur du paramètre entouré des guillemets grâce à la fonction Replace.

Const myFormula As String = "=COUNTIF($F$2:$F$31,[Ville])"
Range("H2").Formula = Replace(myFormula, "[Ville]", Chr(34) & "Marseille" & Chr(34))

Chaque caractère en informatique possède un code ASCII ou ANSI. Les guillemets ont comme code le nombre 34.
Pour insérer les guillemets nous utilisons donc la fonction Chr qui renvoie un caractère de type String correspondant au code ASCII de son argument.

Comment rendre dynamique les références à des cellules dans une formule ?

Lorsque l’on souhaite écrire dans une cellule d’excel une formule qui fait référence à une plage de cellules, il est important de rendre la référence à celle-ci dynamique. Pour cela nous utiliserons également une balise.
Si nous reprenons notre exemple de la formule NB.SI, cela donnera.

Const myFormula As String = "=COUNTIF([data],[Ville])"

La balise nommée data sera remplacée par l’adresse de la plage et la balise nommée Ville par la valeur du critère à compter
Voici la procédure complète utilisée

Sub InsertFormula()
 ' Déclaration ds variables et constantes
 Const myFormula As String = "=COUNTIF([data],[Ville])"
 Dim rng As Range, rngData As Range
 Dim newFormula As String
 ' Attribution des variables objets rng et rngData
 Set rng = ThisWorkbook.Worksheets("db").Range("A1").CurrentRegion
 With rng ' Calcul la plage de données
  ' 6ème colonne des données après déplacement d'1 ligne et redimensionnement de la plage
  Set rngData = .Offset(1).Resize(.Rows.Count - 1).Columns(6)
 End With
 ' Remplacement des balises
 newFormula = Replace(myFormula, "[Ville]", Chr(34) & "Marseille" & Chr(34))
 newFormula = Replace(newFormula, "[data]", rngData.Address)
 ' Ecriture de la formule
 ThisWorkbook.Worksheets("db").Range("H2").Formula = newFormula
End Sub

Nous avons utilisé une variable intermédiaire nommée newFormula pour effectuer le remplacement des balises contenues dans la constante myFormula pour rendre l’exemple plus lisible.
Bien entendu nous aurions pu nous passer de cette variable en effectuant ce remplacement immédiatement mais cela aurait rendu sa lecture plus indigeste dans cette présentation.

With ThisWorkbook.Worksheets("db").Range("H2")
.Formula = Replace(Replace(myFormula, "[Ville]", Chr(34) & "Marseille" & Chr(34)), "[data]", rngData.Address)
End With